Import Heat Flow tabular load using APDL Commands object

Options
Nikos Kallitsis
Nikos Kallitsis Member, Employee Posts: 24
First Anniversary First Comment Ansys Employee Name Dropper
edited June 2023 in Structures

I have a Heat Flow table in .csv format, with the timesteps in the first column and the load values in the second column.

How can I import this load and apply it to a Face in Mechanical using APDL commands?

Tagged:

Comments

  • Nikos Kallitsis
    Nikos Kallitsis Member, Employee Posts: 24
    First Anniversary First Comment Ansys Employee Name Dropper
    Options

    You can import a Heat Flow load using APDL commands by following these steps:

    1. Create a Named Selection of the face you want to apply the load to, e.g., SelectedFaces.
    2. Count the number of timesteps you want to import and measure the area of the SelectedFaces.
    3. Insert an APDL Commands Object in the analysis module containing this script:
    inputs = ??? !Specify number of data points (excluding headers)
    surfaceArea = ??? !Manual input of surface area of NS (SelectedFaces)
    
    /PREP7
    *DIM, heatFlowData, TABLE, inputs, 1, 1, TIME !Create a table to store data points with time as the primary variable
    *TREAD, heatFlowData, 'YourDrive:\File\Path\YourFile', 'CSV', , 1 !Read data points from .csv, skipping 1st line
    
    *TOPER, heatFluxData, heatFlowData, ADD, heatFlowData, 1/surfaceArea, 0, 0 !Convert heat flow to heat flux
    
    *GET, maxET, ELEM, 0, TYPM !Maximum number of existing element types
    newET = maxET+1 !New element type number
    
    ET, newET, SURF152 !New element type to apply heat flux to
    KEYOPT, newET, 8, 1 !Include heat flux
    
    CMSEL, S, SelectedFaces
    ESLN
    TYPE, newET
    ESURF, 0
    
    ALLSEL, ALL
    
    /SOLU
    ESEL, S, TYPE, , newET
    SF, ALL, HFLUX, %heatFluxData% !Apply heat flux load
    
    ALLSEL, ALL
    
    • The inputs and surfaceArea parameters should be input manually by the user.
    • The first row of the data is assumed to be the headers, and therefore it's skipped.
    • In order to apply the heat flow load to the face(s), the load must be converted to heat flux. Thus, the load values are divided by the surface area. Be careful with the units used.
    • The heat flux load is applied to surface elements of type SURF152.


  • salim yagoub
    salim yagoub Member Posts: 2
    First Comment
    Options

    what if i wanna upload heat flux for each element ID csv table? i tried couple ways but didnt work unfortunately.